many newbies seem to believe that it is possible to create one ultimate fight plan (fp) that all fighters can use and win with, this is not the case. every fighter is different and it is foolish to believe that every fight can be won the same way with the same fp. this help file attempts to teach you how to write good fps.
generally speaking, it reads top to bottom, and the last conditional that is true kicks in (is used). some newbies find this fact confusing as they sometimes believe its the first line kick in. this means the more important lines should be at the bottom of the section.
"x)" means this line won't kick in unless it is round x or later. if the line below it has no "x)" at the front, it assumes the it is the same as the last "x)". a "x)" need not be present for every round, "x)" is the same as "round >= x".
eg.
1) 4B/8/8;
if score < 0 then 8/4/8;
4) 6/6/8;
if score < 1 then 8/4/8;
6) if score < 2 then 10/4/6;
line 1 & 2 can only kick in in rounds 1-3 since round 4 is started with a line that will always be used (unconditional). lines 3 & 4 can be used from round 4 till the end of the fight since there is no unconditional line below it. line 5 can be used in round 6 till the fight has ended also.
so if the score = 1 in round 5 the fighter will use 6/6/8, but if that round is tied and the score = 1 in round 6 the fighter will switch to 10/4/6;
don't make them big and confusing, if you know what every line is doing then you will be set. sometimes fps have to big to cover every possibility, this makes it harder to know what it will do in any given situation, and if you don't look at it for a while then you may forget how it worked.
you also need stucture. personally my fps are split into 5 sections, early rounds, middle rounds, late rounds, round 12, global.
eg.
# early rounds
1) 4B/8/8;
# middle rounds
4) 6B/7/7;
if opp < 2 then 5B/10/5;
if score < 0 then 7/5/8;
if endurance_percent < 100 - (round - 1) * 5 then 1/1/8 (clinch);
# late rounds
8) 8/5/7;
if score > 2 then 5H/10/5
if score < round - 11 then 12/1/7 (outside);
if score < round - 12 then 5H/11/4;
if score < round - 13 then 5B/10/5;
if endurance_percent < 100 - (round - 1) * 5 then 1/1/8 (clinch);
# round 12
12) 13/1/6 (outside);
if score > 1 then 6H/7/7;
if score = 1 then 9/4/7;
if score = -1 then 5H/11/4;
if score < -1 then 5H/10!/5 (allout);
# global
1) if endurance_percent < 45 and opp > 0 then towel;
1) if score > 14 - round then 4H/6/10;
1) if score > 14 - round and opp < 2 then 4H/9/7;
stop
by no means does this particular fp allow you to beat everyone and don't expect it to! it's the format i'm try to convey. most of my fps follow this format and consequently this makes most of my fps of similar size of about 25-35 lines or so.
as you can see each section (except global) start with an unconditional line, this ensures that none of the previous lines kick in. essentially it is four mini fps, this keeps it simple.
notice in the first section i didn't use any conditionals, you don't want to be sucked in early and get flashed. stay efficient and let him stuff around. middle rounds start in round 4 or 5, it doesn't matter which you use, unless you are planning something in the early rounds, in that case, starting the middle rounds in round 5 may be better so you get more time.
the same applies to the late rounds, you can use 8 or 9. i change mine each fight, depending on how i feel at the time, this also makes one unpredictable somewhat. the idea of having a "round 12 only" section is to make sure i do the right thing at the right time. you don't want to rest or target the body if you are losing, nor use 13/1/6 if you are up by 3 points.
globals are the conditionals i use for the entire fight. in the fp above, it includes a towel line and a conditional determining if i have won. other lines like "if endurance_percent > 50 and opp < 1 then 5H/11/4;" or "if warnings = 0 then cheat;" could be also used.
involves slaping till you lose a round then going for stun/KD/KO and slapping again. to make this really effective, you must first slap at rate where he must open up so much that you can at least stun him if not KO him. eg. if you use 8/1/11 (outside), they open must open up at least enough to take a round off you. say they use 10/1/9 (ring), your roundslost condition will now go up to 1.
now that you have them where you want them, it's time to stun/KD/KO, how aggressive you are is up to you, but don't forget that your opponent may of won the round with some POW eg. 10/4/6 (ring) so be careful of allouting. 6H/11!/3 (inside/counter/ropes) is usually best.
now that you have stunned them, its time to go back to slapping, hopefully while their "mystuns" conditional will make them do something like 4H/6/10. here you may open up more or less based on what you think they will do. if you think the will use 4H/6/10 then 6/1/13 (outside) will be plenty, if you think they won't hide but rather open up more then you may need to be more aggressive.
how to implement:
1) 8/1/11 (outside);
if roundslost > 0 and mystuns + hisstuns = 0 then 6H/11!/3 (counter);
5)...
this is our stun checker: mystuns + hisstuns = 0 basically if their are ANY stuns then you will continue to use 8/1/11 (outside), usually that stun will come from you trying to stun them and either you opened up to much or you did in fact get them. the unaccounted for situation is that of your opponent trying to stun you first, if this happens, you don't particularly want to open up to try and stun him anyway. if you don't get stunned and you don't lose a round then you won't flash, but that's ok, you have a big lead.
you don't even have to use "roundslost > 0", you could use > 1 instead, especially if they are expecting you to flash them after one lost round. it can also used to make the opponent open up more if you use roundslost > 0 to slap harder then KO them after roundslost > 1.
how to implement:
1) 6/1/13 (outside);
if roundslost > 0 then 9/1/10 (outside);
if roundslost > 1 and mystuns + hisstuns = 0 then 6H/11!/3 (counter);
6)...
i use this more commonly against speedier fighters, because 6/1/13 could be beaten by 6/7/7 (feint) and that is not good to flash against if they have good STR or some KP. so by ensuring that before you flash you have his AGG up around 9 or more you greatly increase your flash success rate.
because you need to lose two rounds for this to even kick in, you may want more than four rounds to work with.
involves slapping until he opens up to try and deal more damage, then KOing at that point. slap with low aggression so that you barely win rounds vs 5B/8/7, this means 6/1/13 (outside) usually. using the endurance_percent conditional we measure tiredness, if you are getting more tired than you should be, then you KO him.
how to implement:
1) 6/1/13 (outside);
if endurance_percent < 100 - (round - 1) * 5 and hisstuns + mystuns > 0 then 5H/11!/4 (counter);
5)...
we use the stun meter again to make sure we don't try and go for the KO more than once. if it didn't work the first time, it's too risky to try again because your opponent will be dealing large amounts of endurance damage as you try to KO him. KP dancers can use this tactic and the run, stun, run tactics together to ensure they win the early rounds and don't take too much damage in the process.
very similar to the "Endurance Test Tactic" above, but it is used against smarter opponents. managers will often know how much endurance they will inflict in the early rounds so they can use 5B/10/5 to set off your line and then revert back to 4H/8/8 expecting the flash to come. if the flash fails, the smarter managers will often switch back to 5B/10/5 to further hurt you, because they don't expect a second flash. this is where the waiting comes in.
how to implement:
1) 6/1/13 (outside);
if endurance_percent < 90 and hisstuns + mystuns > 0 then 5H/11!/4 (counter);
5)...
in the situation i mentioned above where the smart manager will switch expecting the flash, the KP fighter won't try to flash just yet (hard to take 10% with 13 DEF). he is waiting for the opponent to use 5B/10/5 more than once. on that second occurance, the opponent is obviously being cocky and so you flash him the round after. 90% i have found works best because at 85% you are too tired and 95% is too little. 90% is two hard slugging rounds, and one can assume with two hard slugging rounds, there will be a third. the other bonus that this option provides is that it is unscoutable and can not be easily accounted for in an fp. an opponent will have a tough time determining that you are more or less tired than 90%. at 90% you have not had a drop in endurance reporting (ie. you are still "doesn't need to rest") so to them it may look as though the flash round is completely random. another thing is that the number doesn't even need to be 90%!
this strategy is hard to stop but your fighter must be able to overcome the predetermined endurance deficit because you are only using 1 POW and the only endurance loss they will suffer is from fatigue.
this strategy involves the assumption that while an opponent is winning by a decent margin, he will lower his AGG to reduce IPs. the opponent must be smart enough to be able to think like this or else it won't be effective. since you are losing rounds you better be dealing a good portion of endurance damage to ensure you get rounds later. therefore, this plan is best for fighters with a STR advantage and a SPD disadvantage.
how to implement:
1) 5B/8/7 (inside);
if endurance_percent > 100 - (round - 1) * 3 then 5B/9/6 (inside);
if warnings = 0 then cheat;
5) 5B/9/6 (inside);
if score < -1 then 6/7/7 (inside);
...
as you can see, the score conditional will only kick in when your opponent reads "if score > 1" which is when they are likely to drop AGG. this makes winning rounds easier. you can't let the score blow out too far because you risk losing or the opponent using too much DEF to be able to wear them down effectively. another version is:
1) 5B/8/7 (inside);
if endurance_percent > 100 - (round - 1) * 3 then 5B/9/6 (inside);
if warnings = 0 then cheat;
5) 5B/9/6 (inside);
if score < round - 10 then 8/5/7 (inside);
if score < round - 11 then 5H/11/4 (inside);
...
using soft score conditionals rather than the hard score lines. this will make your wait as long as possible to win rounds, meaning he will let the opponent be up by as much as fours points before (hopefully) winning a few rounds. if he doesn't win the round, the tired opponent beat an 8 AGG line, so you try and knock him out. this version favours fighters that are much stronger and slower than their opponent.
a good strategy for speedy fighters with good STR or KP is to fight from ahead. when fighting from ahead you force your opponent to take open up to stay in the game. you use your SPD to win the rounds and bring the STR or KP into it a little later.
how to implement:
1) 5/6/9 (feint);
if roundslost > 0 and score < 0 then 8/4/8 (feint);
5) 4B/8/8 (ring);
if score < 3 then 7/5/8 (feint);
if score < 2 then 9/3/8 (feint);
...
by having a lead this large, you can make sluggers resort to dancing more quickly so they don't lose before round 10. if the slugger starts dancing, you take less IPs. the turnaround is if the slugger doesn't open up to stop you winning rounds so easily, then you can take more IPs. you can see that the FP above shows "5) 4B/8/8 (ring);", this means he will go efficiently to the body when up by three or more. if the opponent is dancing, this can allow a weaker fighter to build and endurance advantage. 4B/8/8 (ring) is the safe option, you could open up to 4B/10/6 (ring) if you don't have KP (because without KP you are more efficient).
if you do have KP there is a good chance you would be tired, so using less POW and more DEF in the fp above would be better for KP fighters. choosing round 6 or 7 to flash is hard to anticipate and with a large lead in score, your opponent will rarely sit and wait for a flash that may not even come (you may choose take the couple extra rounds needed and play it safe). here is the soft score version:
1) 5/6/9 (feint);
if roundslost > 0 and score < 0 then 8/4/8 (feint);
5) 8/3/9 (feint);
if score < 2 then 10/3/7 (feint);
if score > 10 - round then 4H/10!/6 (allout);
...
this version will make your fighter wait until you are close to winning and then go for the KO. this is primarily a KP fighter strategy becasue there is no body targeting involved only an aggressive head attack so late that if the opponent is not trying to win the round they will lose. it is a good idea to have rest rounds with this because KP fighters are endurance inefficient.